Saltar al contenido principal

Text.Combine

Concatena una lista de valores de texto en un valor de texto.

Syntax​

Text.Combine(
    texts as list,
    optional separator as text
) as text

Remarks​

Devuelve el resultado de combinar la lista de valores de texto, texts, en un único valor de texto. Se omiten los valores null presentes en texts. Se puede especificar separator opcional usado en el texto combinado final.

Examples​

Example #1​

Combinar los valores de texto "Seattle" y "WA".

Text.Combine({"Seattle", "WA"})

Result:

"SeattleWA"

Example #2​

Combine los valores de texto "Seattle" y "WA" separados por una coma y un espacio.

Text.Combine({"Seattle", "WA"}, ", ")

Result:

"Seattle, WA"

Example #3​

Combine los valores "Seattle", null y "WA" separados por una coma y un espacio. (Tenga en cuenta que se ignora null.)

Text.Combine({"Seattle", null, "WA"}, ", ")

Result:

"Seattle, WA"

Example #4​

Combine el nombre, la inicial intermedia (si está presente) y el apellido en el nombre completo de la persona.

let
    Source = Table.FromRecords({
        [First Name = "Doug", Middle Initial = "J", Last Name = "Elis"],
        [First Name = "Anna", Middle Initial = "M", Last Name = "Jorayew"],
        [First Name = "Rada", Middle Initial = null, Last Name = "Mihaylova"]
    }),
    FullName = Table.AddColumn(Source, "Full Name", each Text.Combine({[First Name], [Middle Initial], [Last Name]}, " "))
in
    FullName

Result:

Table.FromRecords({
    [First Name = "Doug", Middle Initial = "J", Last Name = "Elis", Full Name = "Doug J Elis"],
    [First Name = "Anna", Middle Initial = "M", Last Name = "Jorayew", Full Name = "Anna M Jorayew"],
    [First Name = "Rada", Middle Initial = null, Last Name = "Mihaylova", Full Name = "Rada Mihaylova"]
})

Category​

Text.Transformations