Table.RemoveMatchingRows

Supprime toutes les occurrences des lignes spécifiées de la table.

Syntax

Table.RemoveMatchingRows(
    table as table,
    rows as list,
    optional equationCriteria as any
) as table

Remarks

Supprime toutes les occurrences des lignes spécifiées de la table.

• table : table dans laquelle rechercher.
• rows : liste contenant des informations sur les lignes à supprimer.
• equationCriteria : (Facultatif) Spécifie comment l’égalité est déterminée lors de la comparaison des valeurs. Ce paramètre peut être une fonction de sélection de clé, une fonction de comparaison ou une liste des colonnes de la table à utiliser pour comparer les lignes.

Examples

Example #1

Supprimer toutes les lignes où [a = 1] dans la table spécifiée.

Table.RemoveMatchingRows(
    Table.FromRecords({
        [a = 1, b = 2],
        [a = 3, b = 4],
        [a = 1, b = 6]
    }),
    {[a = 1]},
    "a"
)

Result:

Table.FromRecords({[a = 3, b = 4]})

Example #2

Supprimer les commandes annulées, sans tenir compte de la casse.

let
    CurrentOrders = #table(type table[OrderID = number, Product = text, Quantity = number],
    {
        {101, "Widget", 5},
        {102, "Gadget", 3},
        {103, "Widget", 5}
    }),
    CanceledOrders = {
        [OrderID = 103, Product = "widget", Quantity = 5]
    },
    FilteredOrders = Table.RemoveMatchingRows(CurrentOrders, CanceledOrders, Comparer.OrdinalIgnoreCase)
in
    FilteredOrders

Result:

#table(type table[OrderID = number, Product = text, Quantity = number],
{
    {101, "Widget", 5},
    {102, "Gadget", 3}
})

Example #3

Supprimer toutes les tâches de maintenance qui ont lieu pendant les jours fériés aux États-Unis.

let
    MaintenanceSchedule = #table(type table [Task = text, Date = date],
    {
        {"HVAC Check", #date(2025, 7, 10)},              // Not a holiday
        {"Window Washing", #date(2025, 9, 1)},           // Labor Day
        {"Fire Drill", #date(2025, 9, 17)},              // Not a holiday
        {"Light Bulb Replacement", #date(2025, 11, 27)}  // Thanksgiving
    }),

    USHolidays = {
        [Date = #date(2025, 1, 1)],   // New Year's Day
        [Date = #date(2025, 7, 4)],   // Independence Day
        [Date = #date(2025, 9, 1)],   // Labor Day
        [Date = #date(2025, 11, 27)], // Thanksgiving
        [Date = #date(2025, 12, 25)]  // Christmas
    },

    FilteredSchedule = Table.RemoveMatchingRows(
        MaintenanceSchedule,
        USHolidays,
        {"Date"}
    )
in
    FilteredSchedule

Result:

#table(type table[Task = text, Date = date],
{
    {"HVAC Check", #date(2025, 7, 10)},
    {"Fire Drill", #date(2025, 9, 17)}
})

Category

Table.Membership