Hop til hovedindhold

Table.FromList

Konverterer en liste til en tabel ved at anvende den angivne opdelingsfunktion på hvert element på listen.

Syntax​

Table.FromList(
    list as list,
    optional splitter as function,
    optional columns as any,
    optional default as any,
    optional extraValues as ExtraValues.Type
) as table

Remarks​

Konverterer en liste, list, til en tabel ved at anvende den valgfrie opdelingsfunktion, splitter, på hvert element på listen. Det antages som standard, at listen er en liste over tekstværdier, der opdeles med kommaer. Den valgfrie columns kan være antallet af kolonner, en liste over kolonner eller en tabeltype. De valgfrie default og extraValues kan også angives.

Examples​

Example #1​

Opret en tabel ud fra en liste ved hjælp af standardopdelingsfunktionen.

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    null,
    {"Letter", "Example Word"}
)

Result:

Table.FromRecords({
    [Letter = "a", #"Example Word" = "apple"],
    [Letter = "b", #"Example Word" = "ball"],
    [Letter = "c", #"Example Word" = "cookie"],
    [Letter = "d", #"Example Word" = "door"]
})

Example #2​

Opret en tabel ud fra en liste ved hjælp af en brugerdefineret opdelingsfunktion.

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    Splitter.SplitByNothing(),
    {"Letter and Example Word"}
)

Result:

Table.FromRecords({
    [#"Letter and Example Word" = "a,apple"],
    [#"Letter and Example Word" = "b,ball"],
    [#"Letter and Example Word" = "c,cookie"],
    [#"Letter and Example Word" = "d,door"]
})

Example #3​

Opret en tabel ud fra listen ved hjælp af opdelingsfunktionen Record.FieldValues.

Table.FromList(
    {
        [CustomerID = 1, Name = "Bob"],
        [CustomerID = 2, Name = "Jim"]
    },
    Record.FieldValues,
    {"CustomerID", "Name"}
)

Result:

Table.FromRecords({
    [CustomerID = 1, Name = "Bob"],
    [CustomerID = 2, Name = "Jim"]
})

Category​

Table.Table construction