Hop til hovedindhold

Table.TransformColumns

Transformerer værdierne i en eller flere kolonner.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

Transformerer table ved at anvende hver kolonnehandling, der er angivet i transformOperations (hvor formatet er { column name, transformation } eller { column name, transformation, new column type }). Hvis der er angivet en defaultTransformation, anvendes den på alle kolonner, der ikke er angivet i transformOperations. Hvis en kolonne, der er angivet i transformOperations, ikke findes, udløses der en undtagelse, medmindre den valgfri parameter missingField angiver et alternativ (f.eks. MissingField.UseNull eller MissingField.Ignore).

Examples​

Example #1​

Konvertér tekstværdierne i kolonnen [A] til talværdier og talværdierne i kolonne [B] til tekstværdier.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Konvertér talværdierne i den manglende kolonne [X] til tekstværdier, og ignorer kolonner, der ikke findes.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Konvertér talværdierne i den manglende kolonne [X] til tekstværdier, og benyt som standard null for kolonner, der ikke findes.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

Øg talværdierne i kolonne [B] gradvist, konvertér dem til tekstværdier, og konvertér alle andre kolonner til tal.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation