Text.ToBinary

Koder tekst til et binært format.

Syntax

Text.ToBinary(
    text as text,
    optional encoding as TextEncoding.Type,
    optional includeByteOrderMark as logical
) as binary

Remarks

Koder en tekstværdi til en binær værdi ved hjælp af den angivne kodning.

• text: Den tekst, der skal kodes.
• encoding: (Valgfrit) Den kodning, der bruges til at konvertere teksten til binær. Brug BinaryEncoding.Type til at angive kodningstypen. Hvis denne værdi ikke er angivet, er standardværdien BinaryEncoding.Utf8.
• includeByteOrderMark: (Valgfrit) Bestemmer, om en Byte Order Mark (BOM) skal medtages i starten af det binære output. Angiv til sand for automatisk at medtage BOM, ellers falsk. Hvis denne værdi ikke er angivet, er standardværdien false.

Examples

Example #1

Kod tekst til binær, opret en synlig Base64-streng, og afkod den derefter tilbage til tekst.

let
    originalText = "Testing 1-2-3",

    // Default UTF-8 binary
    binaryData = Text.ToBinary(originalText),

    // Convert binary to viewable Base64 string
    encodedText = Binary.ToText(binaryData, BinaryEncoding.Base64),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData),

    result = [
        OriginalText = originalText,
        BinaryBase64 = encodedText,
        DecodedText = decodedText
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryBase64 = "VGVzdGluZyAxLTItMw==",
    DecodedText = "Testing 1-2-3"
]

Example #2

Kod tekst til binær med en Byte Order Mark (BOM), generer en synlig hexadecimal streng, og afkod den derefter tilbage til tekst.

let
    originalText = "Testing 1-2-3",

    // Convert to binary with BOM
    binaryData = Text.ToBinary(originalText, TextEncoding.Utf16, true),

    // Show binary as hex to demonstrate presence of BOM (fffe)
    binaryAsHex = Binary.ToText(binaryData, BinaryEncoding.Hex),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData, TextEncoding.Utf16),

    // Compare original text and decoded text
    isIdentical = originalText = decodedText,

    result = [
        OriginalText = originalText,
        BinaryHex = binaryAsHex,
        DecodedText = decodedText,
        IsIdentical = isIdentical
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryHex = "fffe540065007300740069006e006700200031002d0032002d003300",
    DecodedText = "Testing 1-2-3",
    IsIdentical = true
]

Category

Text.Conversions from and to text