Text.ToBinary

Codificar texto num formato binário.

Syntax

Text.ToBinary(
    text as text,
    optional encoding as TextEncoding.Type,
    optional includeByteOrderMark as logical
) as binary

Remarks

Codifica um valor de texto num valor binário com a codificação especificada.

• text: o texto a codificar.
• encoding: (opcional) a codificação utilizada para converter o texto em binário. Utilize BinaryEncoding.Type para especificar o tipo de codificação. Se este valor não for especificado, o valor predefinido é BinaryEncoding.Utf8.
• includeByteOrderMark: (opcional) determina se uma marca de ordem de bytes (BOM) deve ser incluída no início da saída binária. Defina como true para incluir automaticamente a BOM; caso contrário, false. Se este valor não for especificado, o valor predefinido é false.

Examples

Example #1

Codificar texto para binário, produzir uma cadeia Base64 visível e, em seguida, descodificá-la novamente para texto.

let
    originalText = "Testing 1-2-3",

    // Default UTF-8 binary
    binaryData = Text.ToBinary(originalText),

    // Convert binary to viewable Base64 string
    encodedText = Binary.ToText(binaryData, BinaryEncoding.Base64),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData),

    result = [
        OriginalText = originalText,
        BinaryBase64 = encodedText,
        DecodedText = decodedText
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryBase64 = "VGVzdGluZyAxLTItMw==",
    DecodedText = "Testing 1-2-3"
]

Example #2

Codificar texto para binário com uma Marca de Ordem de Bytes (BOM), produzir uma cadeia hexadecimal visível e, em seguida, descodificá-la novamente para texto.

let
    originalText = "Testing 1-2-3",

    // Convert to binary with BOM
    binaryData = Text.ToBinary(originalText, TextEncoding.Utf16, true),

    // Show binary as hex to demonstrate presence of BOM (fffe)
    binaryAsHex = Binary.ToText(binaryData, BinaryEncoding.Hex),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData, TextEncoding.Utf16),

    // Compare original text and decoded text
    isIdentical = originalText = decodedText,

    result = [
        OriginalText = originalText,
        BinaryHex = binaryAsHex,
        DecodedText = decodedText,
        IsIdentical = isIdentical
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryHex = "fffe540065007300740069006e006700200031002d0032002d003300",
    DecodedText = "Testing 1-2-3",
    IsIdentical = true
]

Category

Text.Conversions from and to text