Table.SelectColumns

Devolve uma tabela apenas com as colunas especificadas.

Syntax

Table.SelectColumns(
    table as table,
    columns as any,
    optional missingField as MissingField.Type
) as table

Remarks

Devolve table apenas com as columns especificadas.

• table: a tabela fornecida.
• : columnsa lista de colunas da tabela table a devolver. As colunas existentes na tabela devolvida encontram-se na ordem listada em columns.
• missingField: (Opcional) O que fazer se a coluna não existir. Exemplo: MissingField.UseNull ou MissingField.Ignore.

Examples

Example #1

Incluir apenas a coluna [Name].

Table.SelectColumns(
    Table.FromRecords({
        [CustomerID = 1, Name = "Bob", Phone = "123-4567"],
        [CustomerID = 2, Name = "Jim", Phone = "987-6543"],
        [CustomerID = 3, Name = "Paul", Phone = "543-7890"],
        [CustomerID = 4, Name = "Ringo", Phone = "232-1550"]
    }),
    "Name"
)

Result:

Table.FromRecords({
    [Name = "Bob"],
    [Name = "Jim"],
    [Name = "Paul"],
    [Name = "Ringo"]
})

Example #2

Incluir apenas as colunas [CustomerID] e [Name].

Table.SelectColumns(
    Table.FromRecords({[CustomerID = 1, Name = "Bob", Phone = "123-4567"]}),
    {"CustomerID", "Name"}
)

Result:

Table.FromRecords({[CustomerID = 1, Name = "Bob"]})

Example #3

Se a coluna incluída não existir, o resultado predefinição é um erro.

Table.SelectColumns(
    Table.FromRecords({[CustomerID = 1, Name = "Bob", Phone = "123-4567"]}),
    "NewColumn"
)

Result:

[Expression.Error] The field 'NewColumn' of the record wasn't found.

Example #4

Se a coluna incluída não existir, a opção <code>MissingField.UseNull</code> cria uma coluna de valores nulos.

Table.SelectColumns(
    Table.FromRecords({[CustomerID = 1, Name = "Bob", Phone = "123-4567"]}),
    {"CustomerID", "NewColumn"},
    MissingField.UseNull
)

Result:

Table.FromRecords({[CustomerID = 1, NewColumn = null]})

Category

Table.Column operations