List.Accumulate

Acumula un valor de resumen de los elementos de la lista.

Syntax

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

Remarks

Acumula un valor resumen de los elementos de la lista especificada usando el acumulador.

• list: la lista que se va a iterar.
• seed: un valor acumulado inicial.
• accumulator: función que toma el estado actual y el elemento actual y devuelve el nuevo estado.

Examples

Example #1

Acumula el valor de resumen de los elementos de la lista.

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Result:

15

Example #2

Concatena cada palabra de la lista con un espacio entre ellas, pero sin incluir un espacio al principio.

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Result:

"The quick brown fox jumps over the lazy dog."

Example #3

Crea una lista con los tiempos de finalización de un proceso a partir de una fecha de inicio y una lista de tiempos de ejecución del proceso.

let
    #"Process Duration" =
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) =>
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Result:

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}

Category

List.Transformation functions