跳到主要内容

List.Accumulate

从列表中的项累积汇总值。

Syntax​

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

Remarks​

使用累加器从指定列表中的项累积汇总值。

  • list: 要迭代的列表。
  • seed: 初始累计值。
  • accumulator: 一个函数，它接受当前状态和当前项，并返回新状态。

Examples​

Example #1​

从列表中的项累积汇总值。

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Result:

15

Example #2​

将列表中的每个单词连接起来，单词之间用空格分隔，但开头不要包含空格。

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Result:

"The quick brown fox jumps over the lazy dog."

Example #3​

根据开始日期和进程运行时间列表，生成进程完成时间列表。

let
    #"Process Duration" =
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) =>
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Result:

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}

Category​

List.Transformation functions