List.Accumulate

Накапливает сводное значения из элементов в списке.

Syntax

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

Remarks

Накопление итогового значения из элементов списка с использованием аккумулятора.

• list: список для итерации.
• seed: начальное накопленное значение.
• accumulator: функция, которая принимает текущее состояние и текущий элемент, а затем возвращает новое состояние.

Examples

Example #1

Накапливает суммарное значение из элементов в списке.

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Result:

15

Example #2

Сцепление слов из списка с пробелами между ними, без пробела в начале.

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Result:

"The quick brown fox jumps over the lazy dog."

Example #3

Сборка списка времен выполнения процессов на основе даты начала и списка длительности выполнения.

let
    #"Process Duration" =
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) =>
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Result:

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}

Category

List.Transformation functions