Skip to main content

List.Accumulate

Acumulează o valoare rezumat din elementele din listă.

Syntax​

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

Remarks​

Acumulează o valoare rezumat din elementele din lista specificată utilizând acumulatorul.

  • list: Lista de iterație.
  • seed: O valoare acumulată inițial.
  • accumulator: O funcție care preia starea curentă și elementul curent și returnează starea nouă.

Examples​

Example #1​

Acumulează valoarea rezumat din elementele din listă.

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Result:

15

Example #2​

Concatenați fiecare cuvânt din listă cu un spațiu între ele, dar nu includeți un spațiu la început.

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Result:

"The quick brown fox jumps over the lazy dog."

Example #3​

Construiți o listă de ore de finalizare a procesului de la o dată de început și o listă de ore de rulare a procesului.

let
    #"Process Duration" =
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) =>
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Result:

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}

Category​

List.Transformation functions