Table.SplitColumn

Deli navedenu kolonu u skup dodatnih kolona pomoću navedene funkcije razdelnika.

Syntax

Table.SplitColumn(
    table as table,
    sourceColumn as text,
    splitter as function,
    optional columnNamesOrNumber as any,
    optional default as any,
    optional extraColumns as any
) as table

Remarks

Deli navedenu kolonu u skup dodatnih kolona pomoću navedene funkcije razdelnika.

• table: Tabela koja sadrži kolonu koju treba razdeliti.
• sourceColumn:Ime kolone koju treba razdeliti.
• splitter: Funkcija razdelnika koja se koristi za razdeljivanje kolone (primera radi, Splitter.SplitTextByDelimiter ili Splitter.SplitTextByPosition).
• columnNamesOrNumber: Lista novih imena kolona koju treba kreirati ili broj novih kolona.
• default: Zamenjuje vrednost koja se koristi kada nema dovoljno razdeljenih vrednosti da bi se popunile sve nove kolone. Podrazumevana vrednost za ovaj parametar je null.
• extraColumns: Navodi šta je potrebno uraditi ako ima više razdeljenih vrednosti nego novih kolona. Možete da prosledite vrednost nabrajanja ExtraValues.Type ovom parametru. Podrazumevana vrednost je ExtraValues.Ignore.

Examples

Example #1

Razdelite kolonu s imenima na ime i prezime.

let
    Source = #table(type table[CustomerID = number, Name = text, Phone = text],
    {
        {1, "Bob White", "123-4567"},
        {2, "Jim Smith", "987-6543"},
        {3, "Paul", "543-7890"},
        {4, "Cristina Best", "232-1550"}
    }),
    SplitColumns = Table.SplitColumn(
        Source,
        "Name",
        Splitter.SplitTextByDelimiter(" "))
in
    SplitColumns

Result:

#table(type table[CustomerID = number, Name.1 = text, Name.2 = text, Phone = text],
{
    {1, "Bob", "White", "123-4567"},
    {2, "Jim", "Smith", "987-6543"},
    {3, "Paul", null, "543-7890"},
    {4, "Cristina", "Best", "232-1550"}
})

Example #2

Razdelite kolonu s imenima na ime i prezime, a zatim preimenujte nove kolone.

let
    Source = #table(type table[CustomerID = number, Name = text, Phone = text],
    {
        {1, "Bob White", "123-4567"},
        {2, "Jim Smith", "987-6543"},
        {3, "Paul", "543-7890"},
        {4, "Cristina Best", "232-1550"}
    }),
    SplitColumns = Table.SplitColumn(
        Source,
        "Name",
        Splitter.SplitTextByDelimiter(" "),
        {"First Name", "Last Name"})
in
    SplitColumns

Result:

#table(type table[CustomerID = number, First Name = text, Last Name = text, Phone = text],
{
    {1, "Bob", "White", "123-4567"},
    {2, "Jim", "Smith", "987-6543"},
    {3, "Paul", null, "543-7890"},
    {4, "Cristina", "Best", "232-1550"}
})

Example #3

Razdelite kolonu s imenima na ime i prezime, preimenujte nove kolone i popunite prazne ćelije sa "-No Entry-".

let
    Source = #table(type table[CustomerID = number, Name = text, Phone = text],
    {
        {1, "Bob White", "123-4567"},
        {2, "Jim Smith", "987-6543"},
        {3, "Paul", "543-7890"},
        {4, "Cristina Best", "232-1550"}
    }),
    SplitColumns = Table.SplitColumn(
        Source,
        "Name",
        Splitter.SplitTextByDelimiter(" "),
        {"First Name", "Last Name"},
        "-No Entry-")
in
    SplitColumns

Result:

#table(type table[CustomerID = number, First Name = text, Last Name = text, Phone = text],
{
    {1, "Bob", "White", "123-4567"},
    {2, "Jim", "Smith", "987-6543"},
    {3, "Paul", "-No Entry-", "543-7890"},
    {4, "Cristina", "Best", "232-1550"}
})

Example #4

Razdelite kolonu s imenima na ime i prezime, a zatim preimenujte nove kolone. S obzirom na to da može biti više vrednosti od broja dostupnih kolona, kolonu sa prezimenima napravite kao listu koja uključuje sve vrednosti posle imena.

let
    Source = #table(type table[CustomerID = number, Name = text, Phone = text],
    {
        {1, "Bob White", "123-4567"},
        {2, "Jim Smith", "987-6543"},
        {3, "Paul Green", "543-7890"},
        {4, "Cristina J. Best", "232-1550"}
    }),
    SplitColumns = Table.SplitColumn(
        Source,
        "Name",
        Splitter.SplitTextByDelimiter(" "),
        {"First Name", "Last Name"},
        null,
        ExtraValues.List)
in
    SplitColumns

Result:

#table(type table[CustomerID = number, First Name = text, Last Name = text, Phone = text],
{
    {1, "Bob", {"White"}, "123-4567"},
    {2, "Jim", {"Smith"}, "987-6543"},
    {3, "Paul", {"Green"}, "543-7890"},
    {4, "Cristina", {"J.", "Best"}, "232-1550"}
})

Category

Table.Transformation