Text.FromBinary

Bir ikili biçimindeki verilerin kodunu metin olarak çözer.

Syntax

Text.FromBinary(
    binary as binary,
    optional encoding as TextEncoding.Type
) as text

Remarks

Belirtilen kodlama türü kullanılarak verilerin kodu ikili değerden metin değerine çözülür.

• binary: Kodu çözülecek ikili veriler.
• encoding: (İsteğe bağlı) İkili değeri metin değerine dönüştürmek için kullanılan kodlama. Kodlama türünü belirtmek için BinaryEncoding.Type kullanın. Bu değer belirtilmezse varsayılan değer BinaryEncoding.Utf8 olur.

Examples

Example #1

Metni ikili olarak kodlayın, görüntülenebilir bir Base64 dizesi oluşturun ve kodunu çözüm metne geri döndürün.

let
    originalText = "Testing 1-2-3",

    // Default UTF-8 binary
    binaryData = Text.ToBinary(originalText),

    // Convert binary to viewable Base64 string
    encodedText = Binary.ToText(binaryData, BinaryEncoding.Base64),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData),

    result = [
        OriginalText = originalText,
        BinaryBase64 = encodedText,
        DecodedText = decodedText
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryBase64 = "VGVzdGluZyAxLTItMw==",
    DecodedText = "Testing 1-2-3"
]

Example #2

Metni Bayt Sırası İşareti (BOM) ile ikili değere kodlayın, görüntülenebilir bir onaltılık dize oluşturun ve sonra kodunu çözüp metne geri döndürün.

let
    originalText = "Testing 1-2-3",

    // Convert to binary with BOM
    binaryData = Text.ToBinary(originalText, TextEncoding.Utf16, true),

    // Show binary as hex to demonstrate presence of BOM (fffe)
    binaryAsHex = Binary.ToText(binaryData, BinaryEncoding.Hex),

    // Decode back to text
    decodedText = Text.FromBinary(binaryData, TextEncoding.Utf16),

    // Compare original text and decoded text
    isIdentical = originalText = decodedText,

    result = [
        OriginalText = originalText,
        BinaryHex = binaryAsHex,
        DecodedText = decodedText,
        IsIdentical = isIdentical
    ]
in
    result

Result:

[
    OriginalText = "Testing 1-2-3",
    BinaryHex = "fffe540065007300740069006e006700200031002d0032002d003300",
    DecodedText = "Testing 1-2-3",
    IsIdentical = true
]

Category

Text.Conversions from and to text