Table.TransformColumns

Trasforma i valori di una o più colonne.

Syntax

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks

Trasforma table applicando ogni operazione di colonna elencata in transformOperations (dove il formato è { column name, transformation } o { column name, transformation, new column type }). Se viene specificato un defaultTransformation, verrà applicato a tutte le colonne non elencate in transformOperations. Se una colonna elencata in transformOperations non esiste, viene generata un'eccezione, a meno che il parametro facoltativo missingField non specifichi un'alternativa (ad esempio MissingField.UseNull o MissingField.Ignore).

Examples

Example #1

Converte i valori di testo nella colonna [A] in valori numerici e i valori numerici nella colonna [B] in valori di testo.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2

Consente di trasformare i valori numerici nella colonna mancante [X] in valori di testo, ignorando le colonne che non esistono.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3

Converte i valori numerici nelle colonne mancanti [X] in valori di testo. Per le colonne che non esistono, verrà usato il valore predefinito Null.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4

Incrementa i valori numerici nella colonna [B], li converte in valori di testo e converte tutte le altre colonne in numeri.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category

Table.Transformation