Zum Hauptinhalt springen

Table.TransformColumns

Transformiert die Werte einer oder mehrerer Spalten.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

Transformiert table durch Anwenden jedes spaltenbasierten Vorgangs, der in transformOperations aufgeführt ist (wobei das Format { column name, transformation } oder { column name, transformation, new column type } ist). Wenn eine defaultTransformation angegeben ist, wird sie auf alle Spalten angewendet, die nicht in transformOperations aufgeführt sind. Wenn keine Spalte in transformOperations vorhanden ist, wird eine Ausnahme ausgelöst, es sei denn, der optionale Parameter missingField gibt eine Alternative an (z. B. MissingField.UseNull oder MissingField.Ignore).

Examples​

Example #1​

Konvertieren Sie die Textwerte in Spalte [A] in Zahlenwerte und die Zahlenwerte in Spalte [B] in Textwerte.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Konvertieren Sie die numerischen Werte in der fehlenden Spalte [X] in Textwerte. Dabei werden Spalten ignoriert, die nicht vorhanden sind.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Konvertieren Sie die numerischen Werte in der fehlenden Spalte [X] in Textwerte mit dem Standardwert NULL für Spalten, die nicht vorhanden sind.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

Erhöhen Sie die Zahlenwerte in Spalte [B], konvertieren Sie sie in Textwerte, und konvertieren Sie alle anderen Spalten in Zahlen.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation