Ana içeriğe geç

Table.TransformColumns

Bir veya daha fazla sütunun değerlerini dönüştürür.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

table (Biçim { column name, transformation } veya { column name, transformation, new column type } olacak şekilde) transformOperations üzerinde listelenen her sütun işlemini uygulayarak bu işlemi dönüştürür. Bir defaultTransformation belirtilirse, transformOperations üzerinde listelenmeyen tüm sütunlara uygulanır. transformOperations üzerinde listelenen bir sütun yoksa, isteğe bağlı missingField parametresi bir alternatif belirtmediği sürece özel durum oluşur (örneğin, MissingField.UseNull veya MissingField.Ignore).

Examples​

Example #1​

[A] sütunundaki metin değerlerini sayı değerlerine, [B] sütunundaki sayı değerlerini de metin değerlerine dönüştürün.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Eksik [X] sütunundaki sayı değerlerini, mevcut olmayan sütunları yok sayarak metin değerlerine dönüştürün.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Eksik [X] sütunundaki sayı değerlerini, mevcut olmayan sütunlarda varsayılan olarak null şeklinde ayarlayarak metin değerlerine dönüştürün.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

[B] sütundaki sayı değerlerini artırın ve bunları metin değerlerine dönüştürün, diğer tüm sütunları da sayıya dönüştürün.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation