Hoppa till huvudinnehåll

Table.TransformColumns

Omvandlar värdena för en eller flera kolumner.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

Omvandlar table genom att tillämpa varje kolumnåtgärd som listas i transformOperations (där formatet är { column name, transformation } eller { column name, transformation, new column type }). Om en defaultTransformation anges tillämpas den på alla kolumner som inte är listade i transformOperations. Om en kolumn i transformOperations inte finns genereras ett undantag om inte den valfria parametern missingField anger ett alternativ (t.ex. MissingField.UseNull eller MissingField.Ignore).

Examples​

Example #1​

Omvandla textvärdena i kolumnen [A] till talvärden och talvärdena i kolumnen [B] till textvärden.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Omvandla de numeriska värdena i den saknade kolumnen [X] till textvärden, och ignorera kolumner som inte finns.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Omvandla talvärdena i den saknade kolumnen [X] till textvärden, där null används som standard för kolumner som inte finns.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

Öka talvärdena i kolumnen [B] och omvandla dem till textvärden och omvandla alla andra kolumner till tal.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation