Ga naar hoofdinhoud

Table.TransformColumns

Transformeert de waarden van een of meer kolommen.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

Transformeert table door elke kolombewerking toe te passen die wordt vermeld in transformOperations (waarbij de indeling { column name, transformation } of { column name, transformation, new column type }) is. Als een defaultTransformation is opgegeven, wordt deze toegepast op alle kolommen die niet in transformOperations worden vermeld. Als een kolom in transformOperations niet bestaat, wordt er een uitzondering gegenereerd tenzij de optionele parameter missingField een alternatief opgeeft (bijvoorbeeld MissingField.UseNull of MissingField.Ignore).

Examples​

Example #1​

Converteer de tekstwaarden in kolom [A] naar getalwaarden en de getalwaarden in kolom [B] naar tekstwaarden.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Converteer de getalwaarden in ontbrekende kolom [X] naar tekstwaarden en negeer kolommen die niet bestaan.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Converteer de getalwaarden in ontbrekende kolom [X] naar tekstwaarden. Gebruik standaard null voor kolommen die niet bestaan.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

Verhoog de getalwaarden in kolom [B] en converteer ze naar tekstwaarden, en converteer alle andere kolommen naar getallen.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation