Przejdź do głównej zawartości

Table.TransformColumns

Przekształca wartości co najmniej jednej kolumny.

Syntax​

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks​

Przekształca table przez zastosowanie każdej operacji kolumny wymienionej w transformOperations (gdzie format to { column name, transformation } lub { column name, transformation, new column type }). Jeśli element defaultTransformation zostanie określony, operacja zostanie zastosowana do wszystkich kolumn niewymienionych w transformOperations. Jeśli kolumna wymieniona w transformOperations nie istnieje, zgłaszany jest wyjątek, chyba że opcjonalny parametr missingField określa alternatywę (na przykład MissingField.UseNull lub MissingField.Ignore).

Examples​

Example #1​

Przekształć wartości tekstowe w kolumnie [A] na wartości liczbowe, a wartości liczbowe w kolumnie [B] na wartości tekstowe.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2​

Przekształć wartości liczbowe w brakującej kolumnie [X] na wartości tekstowe i ignoruj nieistniejące kolumny.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.Ignore
)

Result:

Table.FromRecords({
    [A = "1", B = 2],
    [A = "5", B = 10]
})

Example #3​

Przekształć wartości liczbowe w brakującej kolumnie [X] na wartości tekstowe i ustaw wartość null jako wartość domyślną w nieistniejących kolumnach.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #4​

Zwiększ wartości liczbowe w kolumnie [B] i przekonwertuj je na wartości tekstowe oraz przekonwertuj wszystkie pozostałe kolumny na liczby.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Category​

Table.Transformation