List.Select

Vraća listu vrednosti koje se podudaraju sa uslovom.

Syntax

List.Select(
    list as list,
    selection as function
) as list

Remarks

Vraća vrednosti sa navedene liste koje zadovoljavaju uslov izbora.

• list: Lista za ispitivanje.
• selection: Funkcija koja određuje vrednosti koje treba izabrati.

Examples

Example #1

Pronalaženje vrednosti sa liste {1, -3, 4, 9, -2} koje su veće od 0.

List.Select({1, -3, 4, 9, -2}, each _ > 0)

Result:

{1, 4, 9}

Example #2

Izaberite datume sa liste koji padaju u subotu ili nedelju.

let
    dates = {
        #date(2025, 10, 20),  // Monday
        #date(2025, 10, 21),  // Tuesday
        #date(2025, 10, 25),  // Saturday
        #date(2025, 10, 26),  // Sunday
        #date(2025, 10, 27)   // Monday
    },
    weekendDates = List.Select(
        dates,
        each Date.DayOfWeek(_, Day.Monday) >= 5
    )
in
    weekendDates

Result:

{
    #date(2025, 10, 25),
    #date(2025, 10, 26)
}

Example #3

Prikažite tabelu aktivnih kupaca sa ukupnim iznosima kupovine većim od 100 USD.

let
    customers = {
        [Name = "Alice", Status = "Active", Purchases = 150],
        [Name = "Bob", Status = "Inactive", Purchases = 200],
        [Name = "Carol", Status = "Active", Purchases = 90],
        [Name = "Dave", Status = "Active", Purchases = 120]
    },
    highValueActiveCustomers = List.Select(
        customers,
        each [Status] = "Active" and [Purchases] > 100
    ),
    resultTable = Table.FromRecords(
        highValueActiveCustomers,
        type table [Name = text, Status = text, Purchases = number]
    )
in
    resultTable

Result:

#table(type table[Name = text, Status = text, Purchases = number],
{
    {"Alice", "Active", 150},
    {"Dave", "Active", 120}
})

Category

List.Selection