List.Select

傳回符合條件的值清單。

Syntax

List.Select(
    list as list,
    selection as function
) as list

Remarks

從指定的清單傳回符合選取條件的值。

• list: 要檢查的清單。
• selection: 決定要選取的值的函式。

Examples

Example #1

找出清單 {1, -3, 4, 9, -2} 中大於 0 的值。

List.Select({1, -3, 4, 9, -2}, each _ > 0)

Result:

{1, 4, 9}

Example #2

從清單中選取落在星期六或星期日的日期。

let
    dates = {
        #date(2025, 10, 20),  // Monday
        #date(2025, 10, 21),  // Tuesday
        #date(2025, 10, 25),  // Saturday
        #date(2025, 10, 26),  // Sunday
        #date(2025, 10, 27)   // Monday
    },
    weekendDates = List.Select(
        dates,
        each Date.DayOfWeek(_, Day.Monday) >= 5
    )
in
    weekendDates

Result:

{
    #date(2025, 10, 25),
    #date(2025, 10, 26)
}

Example #3

顯示購買總計超過 $100 美元的使用中客戶的資料表。

let
    customers = {
        [Name = "Alice", Status = "Active", Purchases = 150],
        [Name = "Bob", Status = "Inactive", Purchases = 200],
        [Name = "Carol", Status = "Active", Purchases = 90],
        [Name = "Dave", Status = "Active", Purchases = 120]
    },
    highValueActiveCustomers = List.Select(
        customers,
        each [Status] = "Active" and [Purchases] > 100
    ),
    resultTable = Table.FromRecords(
        highValueActiveCustomers,
        type table [Name = text, Status = text, Purchases = number]
    )
in
    resultTable

Result:

#table(type table[Name = text, Status = text, Purchases = number],
{
    {"Alice", "Active", 150},
    {"Dave", "Active", 120}
})

Category

List.Selection