Skip to main content

Table.ReplaceValue

แทนที่ค่าหนึ่งด้วยอีกค่าหนึ่งในคอลัมน์ที่ระบุ

Syntax​

Table.ReplaceValue(
    table as table,
    oldValue as any,
    newValue as any,
    replacer as function,
    columnsToSearch as list
) as table

Remarks​

แทนที่ oldValue ด้วย newValue ในคอลัมน์ที่ระบุของ table

Examples​

Example #1​

แทนที่ข้อความ "goodbye" ด้วย "world" ในคอลัมน์ B โดยจับคู่เฉพาะค่าทั้งหมด

Table.ReplaceValue(
    Table.FromRecords({
        [A = 1, B = "hello"],
        [A = 2, B = "goodbye"],
        [A = 3, B = "goodbyes"]
    }),
    "goodbye",
    "world",
    Replacer.ReplaceValue,
    {"B"}
)

Result:

Table.FromRecords({
    [A = 1, B = "hello"],
    [A = 2, B = "world"],
    [A = 3, B = "goodbyes"]
})

Example #2​

แทนที่ข้อความ "ur" ด้วย "or" ในคอลัมน์ B ซึ่งตรงกับส่วนใดๆ ของค่า

Table.ReplaceValue(
    Table.FromRecords({
        [A = 1, B = "hello"],
        [A = 2, B = "wurld"]
    }),
    "ur",
    "or",
    Replacer.ReplaceText,
    {"B"}
)

Result:

Table.FromRecords({
    [A = 1, B = "hello"],
    [A = 2, B = "world"]
})

Example #3​

ทําให้ชื่อของพนักงานในสหรัฐอเมริกาเป็นแบบไม่ระบุตัวตน

Table.ReplaceValue(
    Table.FromRecords({
        [Name = "Cindy", Country = "US"],
        [Name = "Bob", Country = "CA"]
    }),
    each if [Country] = "US" then [Name] else false,
    each Text.Repeat("*", Text.Length([Name])),
    Replacer.ReplaceValue,
    {"Name"}
)

Result:

Table.FromRecords({
    [Name = "*****", Country = "US"],
    [Name = "Bob", Country = "CA"]
})

Example #4​

ทําให้คอลัมน์ทั้งหมดของพนักงานในสหรัฐอเมริกาเป็นแบบไม่ระบุตัวตน

Table.ReplaceValue(
    Table.FromRecords({
        [Name = "Cindy", Country = "US"],
        [Name = "Bob", Country = "CA"]
    }),
    each [Country] = "US",
    "?",
    (currentValue, isUS, replacementValue) =>
        if isUS then
            Text.Repeat(replacementValue, Text.Length(currentValue))
        else
            currentValue,
    {"Name", "Country"}
)

Result:

Table.FromRecords({
    [Name = "?????", Country = "??"],
    [Name = "Bob", Country = "CA"]
})

Category​

Table.Transformation