Přeskočit na hlavní obsah

Date.FromText

Vytvoří datum z místních, univerzálních a vlastních formátů data.

Syntax​

Date.FromText(
    text as text,
    optional options as any
) as date

Remarks​

Vytvoří hodnotu kalendářního data z textové reprezentace.

  • text: Textová hodnota, která se má převést na datum.
  • options: Volitelná hodnota záznamu record, která může být zadána pro upřesnění dalších vlastností. Hodnota record může obsahovat následující pole:
    • Format: Hodnota typu text označující formát, který se má použít. Další informace najdete na https://go.microsoft.com/fwlink/?linkid=2180104 a https://go.microsoft.com/fwlink/?linkid=2180105. Vynechání tohoto pole nebo zadání hodnoty null způsobí, že se datum parsuje podle nejvhodnějšího postupu.
    • Culture: Pokud nemá Format hodnotu null, řídí některé specifikátory formátu jazyková verze Culture. Například pro "en-US" nabývá "MMM" hodnot "Jan", "Feb", "Mar", ..., zatímco pro "ru-RU" nabývá "MMM" hodnot "янв", "фев", "мар", .... Když má Format hodnotu null, řídí výchozí formát, který se má použít, hodnota Culture. Když má Culture hodnotu null nebo není zadaná, použije se Culture.Current.

Pokud chcete podporovat starší pracovní postupy, může být options také textová hodnota. Má stejné chování, jako když options = [Format = null, Culture = options].

Examples​

Example #1​

Převede hodnotu "2010-12-31" na hodnotu date.

Date.FromText("2010-12-31")

Result:

#date(2010, 12, 31)

Example #2​

Umožňuje převod pomocí vlastního formátu a německé jazykové verze.

Date.FromText("30 Dez 2010", [Format="dd MMM yyyy", Culture="de-DE"])

Result:

#date(2010, 12, 30)

Example #3​

Vyhledá datum v gregoriánském kalendáři, které odpovídá začátku roku 1400 v kalendáři Hidžra.

Date.FromText("1400", [Format="yyyy", Culture="ar-SA"])

Result:

#date(1979, 11, 20)

Example #4​

Umožňuje převést italská textová kalendářní data se zkrácenými měsíci ve sloupci s datem publikování na hodnoty kalendářních dat.

let
    Source = #table(type table [Account Code = text, Posted Date = text, Sales = number],
    {
        {"US-2004", "20 gen. 2023", 580},
        {"CA-8843", "18 lug. 2024", 280},
        {"PA-1274", "12 gen. 2023", 90},
        {"PA-4323", "14 apr. 2023", 187},
        {"US-1200", "14 dic. 2023", 350},
        {"PTY-507", "4 giu. 2024", 110}
    }),
    #"Converted Date" = Table.TransformColumns(
        Source,
        {"Posted Date", each Date.FromText(_, [Culture = "it-IT"]), type date}
    )
in
    #"Converted Date"

Result:

#table(type table [Account Code = text, Posted Date = date, Sales = number],
{
    {"US-2004", #date(2023, 1, 20), 580},
    {"CA-8843", #date(2024, 7, 18), 280},
    {"PA-1274", #date(2023, 1, 12), 90},
    {"PA-4323", #date(2023, 4, 14), 187},
    {"US-1200", #date(2023, 12, 14), 350},
    {"PTY-507", #date(2024, 6, 4), 110}
})

Category​

Date