Table.TransformColumns

Перетворює значення одного або кількох стовпців.

Syntax

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks

Перетворює вказану таблицю, застосовуючи кожну операцію над стовпцем зі списку.

• table: таблиця для перетворення.
• transformOperations: перетворення, які потрібно застосувати до таблиці. Формат цього параметра – { column name, transformation } або { column name, transformation, new column type }.
• defaultTransformation: (необов’язково) стандартне перетворення, яке застосовується до всіх стовпців, не перелічених у transformOperations.
• missingField: (необов’язково) указує очікувану дію для відсутніх значень. Якщо стовпець, перелічений у transformOperations, не існує, стається помилка (MissingField.Error), якщо цей параметр не вказує альтернативний варіант. Використайте одне з таких значень:
  • MissingField.UseNull: усі відсутні поля включено як значення null.
  • MissingField.Ignore: усі відсутні поля пропускаються.

Examples

Example #1

Перетворити текстові значення в стовпці [A] на числові, а числові значення в стовпці [B] – на текстові.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2

Перетворити числові значення у відсутньому стовпці [X] на текстові, а для стовпців, що не існують, установити значення null.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #3

Збільшити числові значення в стовпці [B] та перетворити їх на текстові, а також перетворити всі інші стовпці на числові.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Example #4

Перенеси заплановані завдання з обслуговування, які припадають на свято в США, на наступний день або на наступний понеділок, якщо свято припадає на п’ятницю.

let
    MaintenanceSchedule = #table(type table [Task = text, Date = date],
    {
        {"HVAC Check", #date(2025, 7, 10)},         // Not a holiday
        {"Window Washing", #date(2025, 9, 1)},      // Labor Day
        {"Fire Drill", #date(2025, 9, 17)},         // Not a holiday
        {"Light Replacement", #date(2025, 11, 27)}  // Thanksgiving
    }),
    USHolidays = {
        #date(2025, 1, 1),   // New Year's Day
        #date(2025, 7, 4),   // Independence Day
        #date(2025, 9, 1),   // Labor Day
        #date(2025, 11, 27), // Thanksgiving
        #date(2025, 12, 25)  // Christmas
    },
    AdjustedSchedule = Table.TransformColumns(
        MaintenanceSchedule,
        {{"Date", each if List.Contains(USHolidays, _) then
            if Date.DayOfWeek(_, Day.Sunday) = 5 then
                Date.AddDays(_, 3)     // Friday to Monday
            else
                Date.AddDays(_, 1)     // Other to next day
        else _, type date}}
    )
in
    AdjustedSchedule

Result:

#table(type table[Task = text, Date = date],
{
    {"HVAC Check", #date(2025, 7, 10)},
    {"Window Washing", #date(2025, 9, 2)},
    {"Fire Drill", #date(2025, 9, 17)},
    {"Light Replacement", #date(2025, 11, 28)}
})

Category

Table.Transformation