Table.TransformColumns

Transformuojamos vieno ar kelių stulpelių reikšmės.

Syntax

Table.TransformColumns(
    table as table,
    transformOperations as list,
    optional defaultTransformation as function,
    optional missingField as MissingField.Type
) as table

Remarks

Transformuoja nurodytą lentelę, pritaikant kiekvieną stulpelio operaciją iš sąrašo.

• table: lentelė, kurią reikia transformuoti.
• transformOperations: transformacijos, kurias reikia atlikti lentelėje. Šio parametro formatas yra { column name, transformation } arba { column name, transformation, new column type }.
• defaultTransformation: (pasirinktinai) numatytoji transformacija, taikoma visiems stulpeliams, nenurodytiems transformOperations.
• missingField: (pasirinktinai) nurodo numatomą veiksmą trūkstamoms reikšmėms. Jei stulpelis, nurodytas transformOperations, neegzistuoja, pateikiama klaida (MissingField.Error), nebent šis parametras nurodo alternatyvą. Naudokite vieną iš šių reikšmių:
  • MissingField.UseNull: visi trūkstami laukai įtraukiami kaip null reikšmės.
  • MissingField.Ignore: trūkstamų laukų nepaisoma.

Examples

Example #1

Konvertuokite tekstines reikšmes, esančias stulpelyje [A], į skaitines reikšmes, o stulpelyje [B] esančias skaitines reikšmes – į tekstines.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {
        {"A", Number.FromText},
        {"B", Text.From}
    }
)

Result:

Table.FromRecords({
    [A = 1, B = "2"],
    [A = 5, B = "10"]
})

Example #2

Konvertuokite trūkstamo stulpelio [X] reikšmių skaičių į tekstines reikšmes, pagal numatytuosius parametrus pažymėdami null stulpeliuose, kurie neegzistuoja.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"X", Number.FromText},
    null,
    MissingField.UseNull
)

Result:

Table.FromRecords({
    [A = "1", B = 2, X = null],
    [A = "5", B = 10, X = null]
})

Example #3

Padidinkite stulpelio [B] skaitines reikšmes ir konvertuokite jas į tekstines reikšmes bei konvertuokite visus kitus stulpelius į skaičius.

Table.TransformColumns(
    Table.FromRecords({
        [A = "1", B = 2],
        [A = "5", B = 10]
    }),
    {"B", each Text.From(_ + 1), type text},
    Number.FromText
)

Result:

Table.FromRecords({
    [A = 1, B = "3"],
    [A = 5, B = "11"]
})

Example #4

Perkelkite suplanuotas priežiūros užduotis, kurios vyksta JAV švenčių dienomis, į kitą dieną arba, jei šventinė diena yra penktadienis, perkelkite į kitą pirmadienį.

let
    MaintenanceSchedule = #table(type table [Task = text, Date = date],
    {
        {"HVAC Check", #date(2025, 7, 10)},         // Not a holiday
        {"Window Washing", #date(2025, 9, 1)},      // Labor Day
        {"Fire Drill", #date(2025, 9, 17)},         // Not a holiday
        {"Light Replacement", #date(2025, 11, 27)}  // Thanksgiving
    }),
    USHolidays = {
        #date(2025, 1, 1),   // New Year's Day
        #date(2025, 7, 4),   // Independence Day
        #date(2025, 9, 1),   // Labor Day
        #date(2025, 11, 27), // Thanksgiving
        #date(2025, 12, 25)  // Christmas
    },
    AdjustedSchedule = Table.TransformColumns(
        MaintenanceSchedule,
        {{"Date", each if List.Contains(USHolidays, _) then
            if Date.DayOfWeek(_, Day.Sunday) = 5 then
                Date.AddDays(_, 3)     // Friday to Monday
            else
                Date.AddDays(_, 1)     // Other to next day
        else _, type date}}
    )
in
    AdjustedSchedule

Result:

#table(type table[Task = text, Date = date],
{
    {"HVAC Check", #date(2025, 7, 10)},
    {"Window Washing", #date(2025, 9, 2)},
    {"Fire Drill", #date(2025, 9, 17)},
    {"Light Replacement", #date(2025, 11, 28)}
})

Category

Table.Transformation