List.Distinct

Повертає список значень без видалених повторів.

Syntax

List.Distinct(
    list as list,
    optional equationCriteria as any
) as list

Remarks

Повертає список, який містить усі значення в указаному списку з вилученими дублікатами. Якщо вказаний список пустий, результатом буде пустий список.

• list: список, з якого видобуваються унікальні значення.
• equationCriteria: (необов’язково) указує, як визначається рівність під час порівняння значень. Цей параметр може бути функцією селектора ключів, функцією порівняння або списком, що містить як селектор ключів, так і засіб порівняння.

Examples

Example #1

Видалити повтори зі списку {1, 1, 2, 3, 3, 3}.

List.Distinct({1, 1, 2, 3, 3, 3})

Result:

{1, 2, 3}

Example #2

Починаючи з кінця списку, виберіть фрукти з унікальною довжиною назви.

let
    Source = {"Apple", "Banana", "Cherry", "Date", "Fig"},
    Result = List.Distinct(List.Reverse(Source), each Text.Length(_))
in
    Result

Result:

{"Fig", "Date", "Cherry", "Apple"}

Example #3

Починаючи з початку списку, виберіть унікальні назви фруктів, ігноруючи регістр.

let
    Source = {"apple", "Pear", "aPPle", "banana", "ORANGE", "pear", "Banana", "Cherry"},
    Result = List.Distinct(Source, Comparer.OrdinalIgnoreCase)
in
    Result

Result:

{"apple", "Pear", "banana", "ORANGE", "Cherry"}

Example #4

Видобудьте зі списку перші списки з унікальними назвами країн, ігноруючи регістр. Розмістіть видобуті списки в рядках нової таблиці.

let
    Source = {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Usa", #date(2023, 7, 1), 450},
        {"CANADA", #date(2023, 6, 1), 357},
        {"Panama", #date(2023, 6, 2), 20},
        {"panama", #date(2023, 7, 1), 40}
    },
    DistinctByCountry = List.Distinct(
        Source,
        {each _{0}, Comparer.OrdinalIgnoreCase}
    ),
    ToTable = Table.FromRows(DistinctByCountry, {"Country", "Date", "Value"}),
    ChangeTypes = Table.TransformColumnTypes(
        ToTable, {{"Country", type text}, {"Date", type date}, {"Value", Int64.Type}}
    )
in
    ChangeTypes

Result:

#table(type table[Country = text, Date = date, Value = Int64.Type],
{
    {"USA", #date(2023, 8, 1), 567},
    {"canada", #date(2023, 8, 1), 254},
    {"Panama", #date(2023, 6, 2), 20}
})

Category

List.Selection