Table.FromList

通过将指定的拆分函数应用于列表中的每一项，将列表转换为表。

Syntax

Table.FromList(
    list as list,
    optional splitter as function,
    optional columns as any,
    optional default as any,
    optional extraValues as ExtraValues.Type
) as table

Remarks

通过将可选的拆分函数 splitter 应用于列表中的每一项，将列表 list 转换为表。默认情况下，假定列表是用逗号分隔的文本值的列表。可选的 columns 可以是列数、列的列表或 TableType。还可以指定可选的 default 和 extraValues。

Examples

Example #1

使用默认拆分器从列表创建表。

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    null,
    {"Letter", "Example Word"}
)

Result:

Table.FromRecords({
    [Letter = "a", #"Example Word" = "apple"],
    [Letter = "b", #"Example Word" = "ball"],
    [Letter = "c", #"Example Word" = "cookie"],
    [Letter = "d", #"Example Word" = "door"]
})

Example #2

使用自定义拆分器从列表创建表。

Table.FromList(
    {"a,apple", "b,ball", "c,cookie", "d,door"},
    Splitter.SplitByNothing(),
    {"Letter and Example Word"}
)

Result:

Table.FromRecords({
    [#"Letter and Example Word" = "a,apple"],
    [#"Letter and Example Word" = "b,ball"],
    [#"Letter and Example Word" = "c,cookie"],
    [#"Letter and Example Word" = "d,door"]
})

Example #3

使用 Record.FieldValues 拆分器从列表中创建表。

Table.FromList(
    {
        [CustomerID = 1, Name = "Bob"],
        [CustomerID = 2, Name = "Jim"]
    },
    Record.FieldValues,
    {"CustomerID", "Name"}
)

Result:

Table.FromRecords({
    [CustomerID = 1, Name = "Bob"],
    [CustomerID = 2, Name = "Jim"]
})

Category

Table.Table construction